GY9960 Gesture IR-RGB Sensor I2C 3.3V

This is the RGB and Gesture Sensor, a small breakout board with a built in APDS-9960 sensor that offers ambient light and color measuring, proximity detection, and touchless gesture sensing. With this RGB and Gesture Sensor you will be able to control a computer, microcontroller, robot, and more with a simple swipe of your hand.



The APDS-9960 is a serious little piece of hardware with built in UV and IR blocking filters, four separate diodes sensitive to different directions, and an I2C compatible interface. For your convenience the following pins have been broken out: VL (optional power to IR LED), GND (Ground), VCC (power to APDS-9960 sensor), SDA (I2C data), SCL (I2C clock), and INT (interrupt). Each APDS-9960 also has a detection range of 10 -20cm.

Quick Spec

• Model: GY-APDS 9960-3.3
• Chip: APDS-9960
• Power Supply: 3.3V
• Range Detection: 10 - 20cm
• Communication: I2C
• Dimensions: 20 x 15.3mm
• Net Weight: 2g

Schematic

Setting the Jumpers

The front of the module has 2 solder jumpers labeled PS and I2C PU

PS - This jumper connects the power supplies of the sensor and IR LED together. As shipped, the jumper is open so you will need to provide power to both the VCC (2.4 – 3.6V) and VL (3.0 – 4.5V).

I2C PU - This is a 3-way solder jumper used to connect the I2C 10K pull-up resistors to the SDA and SCL circuits. As shipped, this jumper is open.

Pinout

• VL - Power to IR LED. Must be 3.0 – 4.5V
• GND - Ground connects to ground on the MCU
• VCC - Power input. Connects to 3.3V on the MCU (2.4 – 3.6V)
• SDA - I2C Data line. Connects to SDA on MCU
• SCL - I2C Clock line. Connects to SCL on MCU
• INT - Interrupt output active LOW. Output is open-collector so requires pull-up resistor. Connects to an interrupt input on the MCU if used

Sample Code

/*
  APDS9960 - Gesture Sensor Test

  This example reads gesture data from the APDS9960 sensor and prints any
  detected gestures and proximity infor to the Serial Monitor and to a 16x2
  I2C LCD display if attached.

  Gesture directions are as follows:
  - UP:    from header side
  - DOWN:  toward header side
  - LEFT:  from INT pin side
  - RIGHT: toward INT pin side
*/
#include <Arduino_APDS9960.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

LiquidCrystal_I2C lcd(0x27, 16, 2); // set LCD address to 0x27 for 16x2 display
int proximity = 0;

//===============================================================================
//  Initialization
//===============================================================================
void setup() {
  Serial.begin(9600);

  lcd.begin();
  lcd.clear();
  lcd.backlight();      // Make sure backlight is on

  if (!APDS.begin()) {
    Serial.println("Error initializing APDS9960 sensor!");
  }

  // for setGestureSensitivity(..) a value between 1 and 100 is required.
  // Higher values makes the gesture recognition more sensitivee but less accurate
  // (a wrong gesture may be detected). Lower values makes the gesture recognition
  // more accurate but less sensitive (some gestures may be missed).
  // Default is 80 which we are using. 
  APDS.setGestureSensitivity(80);

  Serial.println("Detecting gestures ...");
  lcd.setCursor(0, 1);
  lcd.print("Proximity: ");
}
//===============================================================================
//  Main
//===============================================================================
void loop() {
  // Report proximity reading (0-255) if < 240 to avoid clutter
  if (APDS.proximityAvailable()) {
    proximity = APDS.readProximity();
    if (proximity < 240) {  // Suppress reporting readings when nothing close
      Serial.print("Proximity Detected: ");
      Serial.println (proximity);
      lcd.setCursor(11, 1);  //Move cursor to character 11 on line 1
      lcd.print(proximity);
      lcd.print("   ");     // Erase any extra characters left from last reading
    }
  }

  if (APDS.gestureAvailable()) {
    // a gesture was detected, read and print to serial monitor
    // and LCD if connected
    int gesture = APDS.readGesture();
    lcd.setCursor(0, 0);  //Move cursor to character 0 on line 0
    switch (gesture) {
      case GESTURE_UP:
        Serial.println("Detected UP gesture");
        lcd.print("UP   ");
        break;

      case GESTURE_DOWN:
        Serial.println("Detected DOWN gesture");
        lcd.print("DOWN ");
        break;

      case GESTURE_LEFT:
        Serial.println("Detected LEFT gesture");
        lcd.print("LEFT ");
        break;

      case GESTURE_RIGHT:
        Serial.println("Detected RIGHT gesture");
        lcd.print("RIGHT");
        break;

      default:
        // ignore
        break;
    }
  }
}

Resources

• APDS9960 Datasheet
• Arduino Library

Shipping List

• 1 x GY9960 Gesture IR-RGB Sensor I2C 3.3V
• 1 x 6 Pin SIP Header